© 1988-2012 by Vincent S. Cronin

10.1  Introduction

What causes a given plate to move?  Does it move in response to the jostling of the plates that surround it?  Does it move in response to the sub-lithospheric mantle moving beneath it?  Does it move because of slab pull or ridge push or asthenospheric counterflow (trench pull) or the Eötvös force or...  Does it move by some combination of all of the above, plus some other processes?  These are questions that geodynamicists work to understand.  An important constraint for geodynamicists is the observed motion of plates.

In chapter 9, we worked to understand the instantaneous motion of plates of a multi-plate system relative to each other.  We reconstructed the geohedron associated with the RM2 model of Minster and Jordan (1978).  The vertices of a geohedron represent the individual plates in angular-velocity space.  You can move any individual vertex in angular-velocity space and all of the lines that connect that vertex to the rest of the structure are changed, but the other vertices are not necessarily affected.  Perhaps this suggests to you, as it did to me and many before us, that we should be looking for a way to describe the motion of individual plates in a reference frame external to the lithosphere that will yield the observed motion of plates relative to each other.

We have this impression that if we could find just the right external reference frame, it would give us important hints about what causes the individual plates to move.  That thought has motivated the development of models for the instantaneous motion of individual plates, such as those of Argus and others (2010), Gripp and Gordon (1990, 2002), Argus and Gordon (1990, 1991), Minster and Jordan (1978) and their worthy and numerous predecessors and contemporaries.

We touched on the issue of external reference frames in section 8.4.  In this chapter, we are going to consider how the instantaneous motion of plates relative to each other is related to the instantaneous motion of plates observed in a reference frame that is external to the lithosphere.  This will set the stage for future discussions of finite plate motion.

10.2  User-defined functions

We will use the following user-defined function developed in a previous chapter.

convert2Cart[lat_, long_] := {Cos[lat Degree] Cos[long Degree], Cos[lat Degree] Sin[long Degree], Sin[lat Degree]};

unitVect3D[vect_]:={(vect[[1]]/Norm[vect]),(vect[[2]]/Norm[vect]),(vect[[3]]/Norm[vect])};

findGeogCoord[vect_]:=Module[{lat,long,a,b,c,d,e,f},a=ArcSin[vect[[3]]];b={vect[[1]],vect[[2]],0};c=If[((Abs[vect[[1]]]<(1×(10^(-14))))&&(Abs[vect[[2]]]<(1×(10^(-14))))),{1,1,0},{vect[[1]]/Norm[b],vect[[2]]/Norm[b],0}];d={1,0,0};e=VectorAngle[c,d];f=If[(vect[[2]]<0),(-e),(e)];lat=a(180/π);long=If[((Abs[vect[[1]]]<(1×(10^(-14))))&&(Abs[vect[[2]]]<(1×(10^(-14))))),0,(f(180/π))];{lat,long}];

makeGreatCircle[normal_]:=Module[{a,x1,y1,z1,x2,y2,z2,j1,j2,j3,θ,b},a=Table[{Cos[i Degree],Sin[i Degree],0},{i,0,360,5}];x1={1,0,0};y1={0,1,0};z1={0,0,1};z2=normal;x2=unitVect3D[Cross[z2,z1]];y2=unitVect3D[Cross[z2,x2]];j1={{x1.x2,y1.x2,z1.x2},{x1.y2,y1.y2,z1.y2},{x1.z2,y1.z2,z1.z2}};θ=VectorAngle[z1,z2];j2={{1,0,0},{0,Cos[θ],Sin[θ]},{0,-Sin[θ],Cos[θ]}};j3=Inverse[j1];b=Table[j3.j2.j1.a[[i]],{i,1,Length[a]}];b]

10.3  Data to play with

There is nothing more comforting and useful than data.  Or as Rudolph Trumpy once said, “A bad fossil is worth more than a good hypothesis.”  In this chapter, we will take the same plate system we used in chapter 9 (Pacific, North America, Cocos and Nazca), but we will use velocity values from NUVEL-1A (DeMets and others, 1994) and HS2-NUVEL1A (Gripp and Gordon, 2002).

({{FOR, Moving Plate, Lat (°N), Long (°E), (Subscript[, FOR])(Subscript[ω, Moving]) (°/Myr)}, {PCFC, NOAM, 48.709, -78.167, 0.7486}, {PCFC, COCO, 36.823, -108.629, 1.9975}, {PCFC, NAZC, 55.578, -90.096, 1.3599}, {NOAM, COCO, 27.9, -120.7, 1.36}, {NAZC, COCO, 4.8, -124.3, 0.91}, {NOAM, NAZC, --, --, --}, {hot spots, PCFC, -61.467, 90.326, 1.0613}, {hot spots, NOAM, -74.705, 13.400, 0.3835}, {hot spots, COCO, 13.171, -116.997, 1.1621}, {hot spots, NAZC, 35.879, -90.913, 0.3231}})

In the table above, we have followed convention and used the small-case omega (ω) over the column that presents the magnitude of the angular velocity vector.  The magnitude of the angular velocity vector is also known as the angular speed.  In the rest of this chapter, the small-case omega will be used to denote the angular speed while the capital omega (Ω) will be used when referring to the complete angular-velocity vector.

Once again, the North American-Nazca pole is not included in the published data, and the NOAM-COCO and NAZC-COCO data are expressed to just one decimal place right of the decimal.  Let’s fill-in and enhance.

We start by defining the unit location vectors to the various poles of rotation.

pcfcPnoam=convert2Cart[48.709,-78.167]; noamPpcfc=-1*pcfcPnoam;pcfcωnoam=0.7486;pcfcΩnoam=pcfcωnoam*pcfcPnoam;noamΩpcfc=-1*pcfcΩnoam

pcfcPcoco=convert2Cart[36.823,-108.629]; cocoPpcfc=-1*pcfcPcoco;
pcfcωcoco=1.9975;pcfcΩcoco=pcfcωcoco*pcfcPcoco;cocoΩpcfc=-1*pcfcΩcoco

pcfcPnazc=convert2Cart[55.578,-90.096]; nazcPpcfc=-1*pcfcPnazc;
pcfcωnazc=1.3599;pcfcΩnazc=pcfcωnazc*pcfcPnazc;nazcΩpcfc=-1*pcfcΩnazc

ePpcfc=convert2Cart[-61.467,90.326]; pcfcPe=-1*ePpcfc;

The angular speed of the Pacific plate relative to the hot spot reference frame is 1.0613°/Myr according to Gripp and Gordon (2002).

eωpcfc=1.0613;

ePnoam=convert2Cart[-74.705,13.400]; noamPe=-1*ePnoam;

The angular speed of the North American plate relative to the hot spot reference frame is 0.3835°/Myr according to Gripp and Gordon (2002).

eωnoam=0.3835;

ePcoco=convert2Cart[13.171,-116.997];cocoPe=-1*ePcoco;

The angular speed of the Cocos plate relative to the hot spot reference frame is 0.3835°/Myr according to Gripp and Gordon (2002).

eωcoco=1.1621;

ePnazc=convert2Cart[35.879,-90.913]; nazcPe=-1*ePnazc;eωnazc=0.3231;

Filling-in missing data

We will find the missing data, knowing that

(Subscript[, NAZC])(Subscript[Ω, NOAM]) = (Subscript[, NAZC])(Subscript[Ω, PCFC]) + (Subscript[, PCFC])(Subscript[Ω, NOAM])

and

(Subscript[, NAZC])(Subscript[Ω, NOAM]) = (Subscript[, NAZC])(Subscript[Ω, COCO]) + (Subscript[, COCO])(Subscript[Ω, NOAM])

based on our discussion of closed vector circuits in chapter 8.

noamΩcoco=(eωcoco*ePcoco)-(eωnoam*ePnoam);
noamPcoco=unitVect3D[noamΩcoco];cocoPnoam=-1*noamPcoco;

The angular speed of the Cocos plate relative to North America, and vice versa, is

noamωcoco = Norm[noamΩcoco]

°/Myr.  The pole around which the Cocos plate rotates in a counter-clockwise manner relative to North America is located at the following latitude and longitude.

noamPoleCoco=findGeogCoord[noamPcoco]

We execute the same computations for the Nazca-Cocos and North American-Nazca systems.

nazcΩcoco=(eωcoco*ePcoco)-(eωnazc*ePnazc);
nazcPcoco=unitVect3D[nazcΩcoco];cocoPnazc=-1*nazcPcoco;nazcωcoco=Norm[nazcΩcoco];nazcPoleCoco=findGeogCoord[nazcPcoco];

noamΩnazc=(eωnazc*ePnazc)-(eωnoam*ePnoam);
noamPnazc=unitVect3D[noamΩnazc];nazcPnoam=-1*noamPnazc;noamωnazc=Norm[noamΩnazc];noamPoleNazc=findGeogCoord[noamPnazc];

We find that the polar latitude, longitude and angular speed for the Cocos plate relative to the Nazca plate are

{nazcPoleCoco[[1]],nazcPoleCoco[[2]],nazcωcoco}

and the polar latitude, longitude and angular speed for the North American plate relative to the Nazca plate are

{noamPoleNazc[[1]],noamPoleNazc[[2]],noamωnazc}

10.4  Baby steps:  looking at a 3-plate system

The instantaneous motion of any plates A, B and C relative to each other on our spherical model Earth is described by the following equation

(Subscript[, A])(Subscript[Ω, B]) + (Subscript[, B])(Subscript[Ω, C]) + (Subscript[, C])(Subscript[Ω, A]) = 0.

I asserted that we could use this same equation to describe the instantaneous relative motion of two plates, A and B, relative to a reference frame E that is external to the lithosphere

(Subscript[, A])(Subscript[Ω, B]) + (Subscript[, B])(Subscript[Ω, E]) + (Subscript[, E])(Subscript[Ω, A]) = 0.

We are invoking two different frames of reference in the same vector equation, which seems awkward if not outright dangerous or forbidden.  Consequently, the usual way of presenting this vector expression is to separate the two reference systems on opposite sides of the equation

(Subscript[, A])(Subscript[Ω, B]) = (Subscript[, E])(Subscript[Ω, B]) - (Subscript[, E])(Subscript[Ω, A]).

This equation tells us that the instantaneous angular velocity of plate B as observed from plate A is related to the individual motions of plates A and B in some other reference frame that is outside of the plates.  Changing any one of the three angular velocity vectors in this equation requires a change in at least one of the other angular velocity vectors to maintain the validity of the equation.

Figure 10-1.  Instantaneous vector triangle that is consistent with the equation shown.

Exercise 10-1.  (a) Can plate A rotate around (Subscript[, E])(Subscript[Ω, A]) at the same time that plate B rotates around (Subscript[, E])(Subscript[Ω, B]) if the two angular velocity vectors are not colinear?  Explain your reasoning.
(b) Can plate B rotate around (Subscript[, A])(Subscript[Ω, B]) at the same time that it rotates around (Subscript[, E])(Subscript[Ω, B]) if the two angular velocity vectors are not colinear?  Explain your reasoning.

As with the 3-vector circuits we have investigated, the poles that correspond to these three angular velocity vectors are located on the same great circle at any given instant.

Intersecting great circles and rotational poles

Let’s use these data to investigate the spatial relationships of the rotational poles observed in the frame of reference of plates observed from other plates and in the external frame of reference fixed to the hot spots.  We progress as we did in chapter 9 to establish the vectors normal to each triplet of poles that correspond to one of the following two equations:

(Subscript[, A])(Subscript[Ω, B]) + (Subscript[, B])(Subscript[Ω, C]) + (Subscript[, C])(Subscript[Ω, A]) = 0, or

(Subscript[, A])(Subscript[Ω, B]) + (Subscript[, B])(Subscript[Ω, E]) + (Subscript[, E])(Subscript[Ω, A]) = 0.

normal1a=unitVect3D[Cross[noamPcoco,cocoPpcfc]];normal1b=unitVect3D[Cross[noamPcoco,pcfcPnoam]];normal1c=unitVect3D[Cross[cocoPpcfc,pcfcPnoam]];normal1=unitVect3D[normal1a+normal1b+normal1c];

normal2a=unitVect3D[Cross[noamPcoco,cocoPe]];normal2b=unitVect3D[Cross[ePnoam,noamPcoco]];normal2c=unitVect3D[Cross[cocoPe,ePnoam]];normal2=unitVect3D[normal2a+normal2b+normal2c];

normal3a=unitVect3D[Cross[pcfcPcoco,cocoPe]];normal3b=unitVect3D[Cross[pcfcPcoco,ePpcfc]];normal3c=unitVect3D[Cross[cocoPe,ePpcfc]];normal3=unitVect3D[normal3a+normal3b+normal3c];

normal4a=unitVect3D[Cross[pcfcPnoam,noamPe]];normal4b=unitVect3D[Cross[pcfcPnoam,ePpcfc]];normal4c=unitVect3D[Cross[noamPe,ePpcfc]];normal4=unitVect3D[normal4a+normal4b+normal4c];

Next, we make great circles that are perpendicular to each of the ten normal vectors computed above.

greatCirc1=makeGreatCircle[normal1];greatCirc2=makeGreatCircle[normal2];greatCirc3=makeGreatCircle[normal3];greatCirc4=makeGreatCircle[normal4];

Then we prepare the graphics output files.

out1=Graphics3D[{Opacity[0.85],Sphere[{0,0,0},1]},AspectRatio->1,BoxRatios->{1,1,1},PlotRange->All,PlotRangePadding->0.1,ColorOutput->GrayLevel,Lighting->"Neutral"];

out2=Graphics3D[Line[{{{1,0,0},{0,0,0}},{{0,1,0},{0,0,0}},{{0,0,1},{0,0,0}}}]];

out6=Graphics3D[Line[greatCirc1]];out7 = Graphics3D[Line[greatCirc2]];out8 = Graphics3D[Line[greatCirc3]];out9 = Graphics3D[Line[greatCirc4]];

markers1={{1,0,0},{0,1,0},{0,0,1}};

out3=ListPointPlot3D[markers1,AspectRatio->1,BoxRatios->{1,1,1},PlotStyle->Red,PlotRange->All,PlotRangePadding->0.1];

markers2a={pcfcPnoam,noamPpcfc,pcfcPcoco,cocoPpcfc,noamPcoco,cocoPnoam};

out4a=ListPointPlot3D[markers2a,AspectRatio->1,BoxRatios->{1,1,1},PlotStyle->Directive[Green,PointSize[Large]],PlotRange->All,PlotRangePadding->0.1];

markers3 = {ePnoam, noamPe, ePcoco, cocoPe, ePpcfc, pcfcPe};

out5=ListPointPlot3D[markers3,AspectRatio->1,BoxRatios->{1,1,1},PlotStyle->Directive[Blue,PointSize[Large]],PlotRange->All,PlotRangePadding->0.1];

Show[out1,out2,out6,out7,out8,out9,out3,out4a,out5]

Figure 10-2.  Rotational poles and corresponding great circles for the Cocos-Pacific-North American plate system, from published data (Demets and others, 1994; Gripp and Gordon, 2002).  The X, Y and Z axes are the straight lines through the center of the sphere, and the positive ends of those axes are marked by red dots.  The green dots mark the poles of rotation of one plate relative to another plate.  The blue dots mark the poles of rotation of one plate relative to the external frame of reference.  The great circles are each coplanar with three rotational axes, corresponding to three plate pairs.

The poles of rotation in Figure 10-2 are all located at the intersection of two great circles.  And any great circle that includes one of the blue dots (a pole of rotation of one plate relative to the external reference frame) also contains a second blue dot and a green dot (a pole of rotation of one plate relative to another plate).  This is similar to Figure 3 from Cronin (1987), if I do say so myself.

Figure 10-2 graphically illustrates that the motion of a plate A relative to a plate B is related to the motion of plates A and B in a reference frame external to the lithosphere.  If you have trouble visualizing this, imagine two lovers running across a field of daisies.  The motion of lover A as observed by lover B is related to the motion of lover A relative to the ground and the motion of lover B relative to the ground.  Whether they are running toward each other or away from each other, I will leave to your imagination.

10.5  Three-plate system, part 2

So far, we have just taken the published data and plotted it.  Now, let’s start with the kinematic data for the individual plates as observed from an external reference frame and derive the plate-motion data as observed from another plate using the following equation

(Subscript[, A])(Subscript[Ω, B]) = (Subscript[, E])(Subscript[Ω, B]) - (Subscript[, E])(Subscript[Ω, A]).

Then we will compare our results with the published model.  The complete angular velocity vector will use the symbol Ω in the following expressions, so the angular velocity vector of the Pacific plate in our external reference frame (eΩpacific) is the product of the unit vector to the corresponding rotational pole (ePpcfc) and the angular speed (eωpcfc).

eΩpacific=ePpcfc*eωpcfc;pacificΩe=-1*eΩpacific

Similarly, for North America and Cocos,

eΩnamerica=ePnoam*eωnoam;namericaΩe=-1*eΩnamerica;eΩcocos=ePcoco*eωcoco;cocosΩe=-1*eΩcocos;

We use the equation (Subscript[, A])(Subscript[Ω, B]) = (Subscript[, E])(Subscript[Ω, B]) - (Subscript[, E])(Subscript[Ω, A]) to find the complete angular velocity vector of the Cocos plate relative to North America.

naΩco=eΩcocos-eΩnamerica;

Then we compute the unit vector of naΩco to find the location vector to the corresponding pole of rotation (naPco).

naPco=unitVect3D[naΩco];coPna=-1*naPco

The length of naΩco is the angular speed (naωco).

naωco=Norm[naΩco];

The published geographic coordinates of the North America-Cocos pole are latitude 27.884°N, longitude 120.679°W (negative longitude), with an angular speed of 1.3571°/Myr.  Our computed data for this pole are

{findGeogCoord[naPco],naωco}

Now that we know what we are doing, we repeat the preceding process to find the angular velocity vectors, speeds and poles for the Cocos-Pacific and Pacific-North American plate systems.

paΩco=eΩcocos-eΩpacific;paPco=unitVect3D[paΩco];coPpa=-1*paPco;paωco=Norm[paΩco];

paΩna=eΩnamerica-eΩpacific;paPna=unitVect3D[paΩna];naPpa=-1*paPna;paωna=Norm[paΩna];

We define the unit vectors normal to the various plate triplets

normal5=unitVect3D[Cross[paPna,paPco]];normal6=unitVect3D[Cross[naPco,ePcoco]];normal7=unitVect3D[Cross[paPco,ePcoco]];normal8=unitVect3D[Cross[paPna,ePnoam]];

and use those unit normal vectors to find the corresponding great circles

greatCirc5 = makeGreatCircle[normal5];greatCirc6 = makeGreatCircle[normal6];greatCirc7 = makeGreatCircle[normal7];greatCirc8 = makeGreatCircle[normal8];

Finally, we prepare the new graphics files and display the answer

markers2b={paPna,naPpa,paPco,coPpa,naPco,coPna};

out4b=ListPointPlot3D[markers2b,AspectRatio->1,BoxRatios->{1,1,1},PlotStyle->Directive[Green,PointSize[Large]],PlotRange->All,PlotRangePadding->0.1];

out10 = Graphics3D[Line[greatCirc5]];out11 = Graphics3D[Line[greatCirc6]];out12 = Graphics3D[Line[greatCirc7]];out13 = Graphics3D[Line[greatCirc8]];

Show[out1,out2,out10,out11,out12,out13,out3,out4b,out5]

Figure 10-3.  Rotational poles and corresponding great circles for the Cocos-Pacific-North American plate system, based on the velocities of the three plates relative to an external reference frame (Gripp and Gordon, 2002).  Symbology is the same as Figure 10-2.

Exercise 10-2.  Copy Figure 10-3 in its original form by clicking on the figure so that a graphics box appears around it, then go to the File menu and choose Save Selection As... to make a jpeg, tiff or other type of graphics file of the image.  Then, without changing the orientation of the graphic or deleting the output, change the angular speed of one of the three plates (that is, change eωpcfc, eωcoco, or eωnoam) by a significant amount -- at least 5°/Myr.  The input lines containing the values you might change are in light blue boxes in section 10.3 above.  Evaluate the changed notebook.  Copy the new version of Figure 10-3, and input both of the figures into a word-processing file.  Then answer the following question:  What effect does changing the angular speed of one plate have on a 3-plate system?

After finishing your exercise, remember to change the angular speed back to the original value.

10.6  Three-plate system, part 3

In the last section, we showed that we could compute the angular velocities of plates relative to other plates by starting with the angular velocities of plates relative to a reference frame external to the plates.  Not surprisingly, we can do the same trick in reverse, in at least a couple of ways.  One way that appeals to me because we already have the necessary data is to start with knowledge of the instantaneous angular velocity of one plate relative to an external reference frame, along with knowledge of the angular velocities of the plates relative to each other, and then compute the angular velocities of all other plates relative to the external reference frame, using a form of our familiar equation

(Subscript[, A])(Subscript[Ω, B]) + (Subscript[, B])(Subscript[Ω, E]) + (Subscript[, E])(Subscript[Ω, A]) = 0

and solving for an individual plate

(Subscript[, E])(Subscript[Ω, A]) = (Subscript[, B])(Subscript[Ω, A]) - (Subscript[, B])(Subscript[Ω, E]).

Let’s see if we can re-generate the results of Gripp and Gordon (2002) for the Cocos-Pacific-North American plate system, using data from NUVEL-1A (DeMets and others, 1994) and the reported instantaneous angular velocity of the Pacific plate relative to the Pacific hot spots (eΩpacific).

namerica=pcfcΩnoam-pacificΩe;ωnamerica=Norm[namerica];polenamerica=unitVect3D[namerica];geogNoam=findGeogCoord[polenamerica];

cocos=pcfcΩcoco-pacificΩe;ωcocos=Norm[cocos];polecocos=unitVect3D[cocos];geogCocos=findGeogCoord[polecocos];

According to Gripp and Gordon (2002), the North American pole relative to the hot spots is located at latitude 74.705S° (negative latitude) and longitude 13.400E°, with an angular speed of 0.3835°/Myr.  Our computation yields the following latitude, longitude and speed:

{geogNoam[[1]],geogNoam[[2]],ωnamerica}

Similarly, the Cocos pole relative to the hot spots is located at latitude 13.171N° and longitude 116.997W° (negative longitude), with an angular speed of 1.1621°/Myr.  Our computation yields the following latitude, longitude and speed:

{geogCocos[[1]],geogCocos[[2]],ωcocos}

We could continue in this manner to reproduce the angular velocity data for all of the plates relative to the hot spot reference frame described by Gripp and Gordon (2002).

10.7  A 4-plate system

There are six angular velocity vectors associated with the motion of 4 plates (A, B, C and D) relative to each other, as we noted in chapter 9:

(Subscript[, A])(Subscript[Ω, B]),  (Subscript[, B])(Subscript[Ω, C]),  (Subscript[, C])(Subscript[Ω, A]),  (Subscript[, C])(Subscript[Ω, D]),  (Subscript[, D])(Subscript[Ω, A]),  (Subscript[, B])(Subscript[Ω, D])

To these we add the angular velocity vectors associated with the motion of each plate relative to a reference frame that is external to the lithosphere.

(Subscript[, E])(Subscript[Ω, A]),  (Subscript[, E])(Subscript[Ω, B]),  (Subscript[, E])(Subscript[Ω, C]),  (Subscript[, E])(Subscript[Ω, D])

We are going to plot the great circles associated with all of the corresponding angular velocity triplets, as we did above.  And, as we did above, we will compute the angular velocity vectors of one plate relative to another plate from the angular velocities relative to an external reference frame, rather than just use the published values.

eΩnazca=ePnazc*eωnazc;

paΩnz=eΩnazca-eΩpacific;paPnz=unitVect3D[paΩnz];paωnz=Norm[paΩnz];

nzΩco=eΩcocos-eΩnazca;nzPco=unitVect3D[nzΩco];nzωco=Norm[nzΩco];

naΩnz=eΩnazca-eΩnamerica;naPnz=unitVect3D[naΩnz];naωnz=Norm[naΩnz];

normal9=unitVect3D[Cross[nzPco,paPco]];normal10=unitVect3D[Cross[naPnz,paPna]];normal11=unitVect3D[Cross[nzPco,naPco]];normal12=unitVect3D[Cross[nzPco,ePnazc]];normal13=unitVect3D[Cross[paPnz,ePnazc]];normal14=unitVect3D[Cross[naPnz,ePnazc]];

greatCirc9=makeGreatCircle[normal9];greatCirc10=makeGreatCircle[normal10];greatCirc11=makeGreatCircle[normal11];greatCirc12=makeGreatCircle[normal12];greatCirc13=makeGreatCircle[normal13];greatCirc14=makeGreatCircle[normal14];

out14=Graphics3D[Line[greatCirc9]];out15=Graphics3D[Line[greatCirc10]];out16=Graphics3D[Line[greatCirc11]];out17=Graphics3D[Line[greatCirc12]];out18=Graphics3D[Line[greatCirc13]];out19=Graphics3D[Line[greatCirc14]];

markers4={pcfcPnoam,noamPpcfc,pcfcPcoco,cocoPpcfc,pcfcPnazc,nazcPpcfc,noamPcoco,cocoPnoam,nazcPcoco,cocoPnazc,nazcPnoam,noamPnazc};

out20=ListPointPlot3D[markers4,AspectRatio->1,BoxRatios->{1,1,1},PlotStyle->Directive[Green,PointSize[Large]],PlotRange->All,PlotRangePadding->0.1];

markers5={ePnoam,noamPe,ePcoco,cocoPe,ePnazc,nazcPe,ePpcfc,pcfcPe};

out21=ListPointPlot3D[markers5,AspectRatio->1,BoxRatios->{1,1,1},PlotStyle->Directive[Blue,PointSize[Large]],PlotRange->All,PlotRangePadding->0.1];

Show[out1,out2,out3, out4a, out5, out10,out11,out12,out13,out14,out15,out16,out17,out18,out19,out20,out21]

Figure 10-4.  Rotational poles and corresponding great circles for the Nazca-Cocos-Pacific-North American plate system, based on the velocities of the four plates relative to an external reference frame (Gripp and Gordon, 2002).  Symbology is the same as Figure 10-1.

Exercise 10-3.  If you changed the angular speed of a single plate, what effect might that change have on a 4-plate system?
What effect might that change have on an n-plate system?

We are not going to add more plates the the system for now.  If we added more plates, the illustration of the corresponding great circles would begin to look a lot like a ball of yarn, and that would only be of interest to my cat.

10.9  References and some other relevant texts

Argus, D.F., and Gordon, R.G., 1990, Pacific-North American plate motion from very long baseline interferometry compared with motion inferred from magnetic anomalies, transform faults, and earthquake slip vectors:  Journal of Geophysical Research, v. 95, p. 17,315-17,324.

Argus, D.F., and Gordon, R.G., 1991, No-net-rotation model of current plate velocities incorporating plate motion model NUVEL-1:  Geophysical Research Letters, v. 18, p. 2039-2042.

Argus, D.F., Gordon, R.G., and DeMets, C., 2010, Geologically current motion of 56 plates relative to the no-net-rotation reference frame:  Geochemistry Geophysics Geosystems, v. 12, Q 1101, 13 p., doi:  10.1029/2011GC003751.

Cronin, V.S., 1987, Cycloid kinematics of relative plate motion: Geology, v. 15, p. 1006-1009.

DeMets, C., Gordon, R.G., Argus, D.F., and Stein, S., 1990, Current plate motions:  Geophysical Journal International, v. 101, p. 425-478.

DeMets, C., Gordon, R.G., Argus, D.F., and Stein, S., 1994, Effect of recent revisions to the geomagnetic refersal time scale on estimates of current plate motions:  Geophysical Research Letters, v. 21, p. 2191-2194.

DeMets, C., Gordon, R.G., and Argus, D.F., 2010, Geologically current plate motions:  Geophysical Journal International, doi: 10.1111/j.1365-246X.2009.04491.x

Gripp, A.E., and Gordon, R.G., 1990, Current plate velocities relative to the hotspots incorporating the NUVEL-1 global plate motion model:  Geophysical Research Letters, v. 17, p. 1109-1112.

Gripp, A.E., and Gordon, R.G., 2002, Young tracks of hotspots and current plate velocities:  Geophysical Journal International, v. 150, no. 2, p. 321-361.

McKenzie, D.P., and Parker, R.L., 1967, The north Pacific -- An example of tectonics on a sphere:  Nature, v. 216, p. 1276-1280.

McKenzie, D.P., and Parker, R.L., 1974, Plate tectonics in ω space:  Earth and Planetary Science Letters, v. 22, p. 285-293.

Minster, J.B., Jordan, T.H., Molnar, P., and Haines, E., 1974, Numerical modelling of instantaneous plate tectonics:  Geophysical Journal,  Royal Astronomical Society, v. 36, p. 541-576.

Minster, J.B., and Jordan, T.H., 1978, Present-day plate motions:  Journal of Geophysical Research, v. 83, no. B11, p. 5331-5354.